КриптоПро CSP  

Пример создания запроса на сертификат

Данный пример демонстрирует осуществление создания запроса на сертификат при помощи инструментария CEnroll.
	    
'------------------------------------------------------------------------------
' В данном script-примере создается запрос на сертификат
' в кодировке base64 PKCS10 при помощи инструментария CEnroll.  
'------------------------------------------------------------------------------
 
' Идентификационное имя запроса.
Dim strDN

' Запрос.
Dim strReq


' CEnroll Объект 
Dim objXen

' Обработка ошибок.
On Error Resume Next

' Создание объекта.
Set objXen = CreateObject("CEnroll.CEnroll.1")

' Создание идентификационного имени.
strDN =  "CN=UserName" _
      & ",OU=UserUnit" _
      & ",O=CRYPTO-PRO" _
      & ",L=MOSCOW" _
      & ",S=WA" _
      & ",C=RU"

'Опредление типа провайдера
objXen.ProviderType = 75

'Определение имени провайдера
objXen.ProviderName = "Crypto-Pro GOST R 34.10-2001 Cryptographic Service Provider"

' Создание запроса PKCS #10.
MsgBox("Creating PKCS #10 " & strDN)
strReq = objXen.createPKCS10( strDN, "1.3.6.1.4.1.311.2.1.21")

' Если запрос не создан - сообщение об ошибке.
if ( Err.Number <> 0 ) then
    MsgBox("Error in call to createPKCS10 " & Err.Number)
    err.clear
else
' Если запрос создан - вывод на экран и запись в файл этого запроса.
    MsgBox("Submitting request " & strReq)
    Dim fso, MyFile
    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set MyFile = fso.CreateTextFile("c:\testfile.txt", True)
    MyFile.Write strReq
    MyFile.Close
end if

Wscript.Quit(0)
' Конец примера 
	

Требования:

Windows: 7/8/8.1/10, Server 2008/2008R2/2012/2012R2/2016/2019.